Calcul le nombre de cellule répondant à un critère défini
Exemple : calcul le nombre de cellule possédant les caractères a dans la colonne A.

=NB.SI(A:A;"a")
=NB.SI(A:A;"23")
=NB.SI(A:A;"<=23")

=SOMMEPROD((A1:A8 ="a")*1)

Calcul le nombre de cellule répondant à un critère possèdant des caractères jokers
Exemple : calcul le nombre de cellule possédant les caractères *FF* dans la colonne A.

=SOMMEPROD(NON(ESTERREUR(CHERCHE("FF";A1:A8)))*1)
ou
=SOMMEPROD(ESTNUM(TROUVE("FF";A1:A8;1))*1)

Calcul le nombre de ligne répondant à un double critère défini
Exemple : calcul le nombre de ligne ou l'on retrouve en même temps les caractères FF dans la colonne A et GG dans la colonne B.

=SOMMEPROD((A1:A8="FF")*(B1:B8="GG"))

Calcul le nombre de ligne répondant à un double critère possèdant des caractères jokers
Exemple : calcul le nombre de ligne possédant les caractères *FF* dans la colonne A et les caractères *GG* dans la colonne B.

=SOMMEPROD(NON(ESTERREUR(CHERCHE("FF";A1:A8)))*NON(ESTERREUR(CHERCHE("GG";B1:B8)))*1)
ou
=SOMMEPROD(ESTNUM(TROUVE("FF";A1:A8;1))*(ESTNUM(TROUVE("GG";B1:B8;1))))

Calcul le nombre de cellule non vide dans une colonne (A)
=NB.SI(A:A ; "<>")
ou
=NB.SI(A:A ; ">= ") Faites attention à ne pas oublier l'espace entre = et "
ou
=NBVAL(A:A)

Calcul le nombre de cellule vide dans une plage =NB.VIDE(A1:A8)

Calcul le nombre de cellule contenant une valeur différente dans la plage de donnée sélectionnée
=SOMMEPROD(1/NB.SI(A1:A100;A1:A100)

Nota : si la plage de donnée possède des cellules vides, la formule ne fonctionne pas.

Calcul le nombre de cellule possédant un texte de 4 lettres commençant par "aa"
=NB.SI(A:A;"aa" & "??")

Cette fonction peut aussi s'appliquer à des nombres à la condition que le format texte soit impérativement sélectionné avant d'entré les nombres dans la cellule. La formule devient =NB.SI(A:A;22 & "??")

Calcul le nombre de cellule possédant un texte commençant par "aa" et dont la longueur est inconnue
=NB.SI(A:A;"~aa*")

Cette fonction peut aussi s'appliquer à des nombres à la condition que le format texte soit impérativement sélectionné avant d'entré les nombres dans la cellule. La formule devient =NB.SI(A:A;"~22*")

Calcul le nombre de valeurs comprises entre 2 bornes (entre 200 et 500)
=NB.SI(A:A;">=200")-NB.SI(A:A;">500")
ou
=FREQUENCE(A:A;{500;199})
ou
=SOMMEPROD((A1:A8>=200)*(A1:A8<=500))

Calcul le nombre de dates d'une plage de dates (colonne B), comprises entre deux dates (A1 et A2).
=SOMMEPROD((B1:B8>=A1)*(B1:B8<=A2))